mirror of
https://github.com/romkatv/powerlevel10k.git
synced 2024-11-25 13:30:07 +00:00
52 lines
2.4 KiB
Bash
52 lines
2.4 KiB
Bash
# vim:ft=zsh ts=2 sw=2 sts=2 et fenc=utf-8
|
|
################################################################
|
|
# Powerlevel10k Theme
|
|
# https://github.com/romkatv/powerlevel10k
|
|
#
|
|
# Forked from Powerlevel9k Theme
|
|
# https://github.com/bhilburn/powerlevel9k
|
|
#
|
|
# Which in turn was forked from Agnoster Theme
|
|
# https://github.com/robbyrussell/oh-my-zsh/blob/74177c5320b2a1b2f8c4c695c05984b57fd7c6ea/themes/agnoster.zsh-theme
|
|
################################################################
|
|
|
|
# Temporarily change options.
|
|
'builtin' 'local' '-a' '__p9k_src_opts'
|
|
[[ ! -o 'aliases' ]] || __p9k_src_opts+=('aliases')
|
|
[[ ! -o 'sh_glob' ]] || __p9k_src_opts+=('sh_glob')
|
|
[[ ! -o 'no_brace_expand' ]] || __p9k_src_opts+=('no_brace_expand')
|
|
'builtin' 'setopt' 'no_aliases' 'no_sh_glob' 'brace_expand'
|
|
|
|
(( $+__p9k_root_dir )) || typeset -gr __p9k_root_dir=${POWERLEVEL9K_INSTALLATION_DIR:-${${(%):-%x}:A:h}}
|
|
# Note: leading spaces before `local` are important. Otherwise Antigen will remove `local` (!!!).
|
|
(( $+__p9k_intro )) || typeset -gr __p9k_intro='emulate -L zsh -o no_hist_expand -o extended_glob -o no_prompt_bang -o prompt_percent -o no_prompt_subst -o no_aliases -o no_bg_nice -o typeset_silent
|
|
local -a match mbegin mend reply
|
|
local -i MBEGIN MEND OPTIND
|
|
local MATCH REPLY OPTARG IFS=$'\'' \t\n\0'\''
|
|
[[ -z $_p9k_locale ]] || local LC_ALL=$_p9k_locale'
|
|
|
|
() {
|
|
eval $__p9k_intro
|
|
if (( $+__p9k_sourced )); then
|
|
(( $+functions[_p9k_setup] )) && _p9k_setup
|
|
return 0
|
|
fi
|
|
typeset -gr __p9k_dump_file=${XDG_CACHE_HOME:-~/.cache}/p10k-dump-${(%):-%n}.zsh
|
|
if [[ $__p9k_dump_file != $__p9k_instant_prompt_dump_file ]] && (( ! $+functions[_p9k_preinit] )) && source $__p9k_dump_file 2>/dev/null && (( $+functions[_p9k_preinit] )); then
|
|
_p9k_preinit
|
|
fi
|
|
typeset -gr __p9k_sourced=3
|
|
if [[ -w $__p9k_root_dir && -w $__p9k_root_dir/internal && -w $__p9k_root_dir/gitstatus && ${(%):-%#} == % ]]; then
|
|
local f
|
|
for f in $__p9k_root_dir/{powerlevel9k.zsh-theme,powerlevel10k.zsh-theme,internal/p10k.zsh,internal/icons.zsh,internal/configure.zsh,internal/worker.zsh,internal/parser.zsh,gitstatus/gitstatus.plugin.zsh}; do
|
|
[[ $f.zwc -nt $f ]] || zcompile $f
|
|
done
|
|
fi
|
|
source $__p9k_root_dir/internal/p10k.zsh || true
|
|
}
|
|
|
|
unsetopt local_options
|
|
(( $+__p9k_instant_prompt_active )) && unsetopt prompt_cr prompt_sp || setopt prompt_cr prompt_sp
|
|
|
|
(( ${#__p9k_src_opts} )) && setopt ${__p9k_src_opts[@]}
|
|
'builtin' 'unset' '__p9k_src_opts'
|