mirror of
https://github.com/ohmyzsh/ohmyzsh.git
synced 2024-12-18 02:20:09 +00:00
53 lines
1.9 KiB
Bash
53 lines
1.9 KiB
Bash
# the idea of this theme is to contain a lot of info in a small string, by compressing some parts,
|
|
# and colorcoding, which bring useful visual cues. While limiting the amount of colors and such to keep
|
|
# it easy on the eyes
|
|
# exact return code (when >0) is on the right, so it stays out of the way
|
|
# The visual cues for >0 exit codes will only display once
|
|
# (i.e. they will be reset, even if you hit enter a few times on empty command prompts)
|
|
|
|
typeset -A host_repr
|
|
host_repr=('dieter-ws-a7n8x-arch' "%{$fg_bold[green]%}ws" 'dieter-p4sci-arch' "%{$fg_bold[blue]%}p4")
|
|
|
|
|
|
# local time, color coded after last return code
|
|
time_enabled="%(?.%{$fg[green]%}.%{$fg[red]%})%*%{$reset_color%}"
|
|
time_disabled="%{$fg[green]%}%*%{$reset_color%}"
|
|
time=$time_enabled
|
|
|
|
# user part, color coded after privileges
|
|
local user="%(!.%{$fg[blue]%}.%{$fg[blue]%})%n%{$reset_color%}"
|
|
|
|
# Hostname part. compressed and colorcoded per host_repr array
|
|
# if not found, regular hostname in default color
|
|
local host="@${host_repr[$(hostname)]:-$(hostname)}%{$reset_color%}"
|
|
|
|
# Compacted $PWD
|
|
local pwd="%{$fg[blue]%}%c%{$reset_color%}"
|
|
|
|
PROMPT='${time} ${user}${host} ${pwd} $(git_prompt_info)'
|
|
|
|
# i would prefer 1 icon that shows the "most drastic" deviation from head, but lets see how this works out
|
|
ZSH_THEME_GIT_PROMPT_PREFIX="%{$fg[yellow]%}"
|
|
ZSH_THEME_GIT_PROMPT_SUFFIX="%{$reset_color%} "
|
|
ZSH_THEME_GIT_PROMPT_DIRTY="%{$fg[green]%} %{$fg[yellow]%}?%{$fg[green]%}%{$reset_color%}"
|
|
ZSH_THEME_GIT_PROMPT_CLEAN="%{$fg[green]%}"
|
|
|
|
# elaborate exitcode on the right when >0
|
|
return_code_enabled="%(?..%{$fg[red]%}%? ↵%{$reset_color%})"
|
|
return_code_disabled=
|
|
return_code=$return_code_enabled
|
|
|
|
RPS1='${return_code}'
|
|
|
|
function accept-line-or-clear-warning () {
|
|
if [[ -z $BUFFER ]]; then
|
|
time=$time_disabled
|
|
return_code=$return_code_disabled
|
|
else
|
|
time=$time_enabled
|
|
return_code=$return_code_enabled
|
|
fi
|
|
zle accept-line
|
|
}
|
|
zle -N accept-line-or-clear-warning
|
|
bindkey '^M' accept-line-or-clear-warning
|