mirror of
https://github.com/ohmyzsh/ohmyzsh.git
synced 2024-11-15 18:30:08 +00:00
89 lines
2.8 KiB
Bash
89 lines
2.8 KiB
Bash
# Set terminal window and tab/icon title
|
|
#
|
|
# usage: title short_tab_title [long_window_title]
|
|
#
|
|
# See: http://www.faqs.org/docs/Linux-mini/Xterm-Title.html#ss3.1
|
|
# Fully supports screen, iterm, and probably most modern xterm and rxvt
|
|
# (In screen, only short_tab_title is used)
|
|
# Limited support for Apple Terminal (Terminal can't set window and tab separately)
|
|
function title {
|
|
[[ "$EMACS" == *term* ]] && return
|
|
|
|
# if $2 is unset use $1 as default
|
|
# if it is set and empty, leave it as is
|
|
: ${2=$1}
|
|
|
|
if [[ "$TERM" == screen* ]]; then
|
|
print -Pn "\ek$1:q\e\\" #set screen hardstatus, usually truncated at 20 chars
|
|
elif [[ "$TERM" == xterm* ]] || [[ "$TERM" == rxvt* ]] || [[ "$TERM" == ansi ]] || [[ "$TERM_PROGRAM" == "iTerm.app" ]]; then
|
|
print -Pn "\e]2;$2:q\a" #set window name
|
|
print -Pn "\e]1;$1:q\a" #set icon (=tab) name
|
|
fi
|
|
}
|
|
|
|
ZSH_THEME_TERM_TAB_TITLE_IDLE="%15<..<%~%<<" #15 char left truncated PWD
|
|
ZSH_THEME_TERM_TITLE_IDLE="%n@%m: %~"
|
|
|
|
# Runs before showing the prompt
|
|
function omz_termsupport_precmd {
|
|
if [[ $DISABLE_AUTO_TITLE == true ]]; then
|
|
return
|
|
fi
|
|
|
|
title $ZSH_THEME_TERM_TAB_TITLE_IDLE $ZSH_THEME_TERM_TITLE_IDLE
|
|
}
|
|
|
|
# Runs before executing the command
|
|
function omz_termsupport_preexec {
|
|
if [[ $DISABLE_AUTO_TITLE == true ]]; then
|
|
return
|
|
fi
|
|
|
|
emulate -L zsh
|
|
setopt extended_glob
|
|
|
|
# cmd name only, or if this is sudo or ssh, the next cmd
|
|
local CMD=${1[(wr)^(*=*|sudo|ssh|rake|-*)]:gs/%/%%}
|
|
local LINE="${2:gs/%/%%}"
|
|
|
|
title '$CMD' '%100>...>$LINE%<<'
|
|
}
|
|
|
|
precmd_functions+=(omz_termsupport_precmd)
|
|
preexec_functions+=(omz_termsupport_preexec)
|
|
|
|
|
|
# Keep Apple Terminal.app's current working directory updated
|
|
# Based on this answer: http://superuser.com/a/315029
|
|
|
|
if [[ "$TERM_PROGRAM" == "Apple_Terminal" ]] && [[ -z "$INSIDE_EMACS" ]]; then
|
|
# Emits the control sequence to notify Terminal.app of the cwd
|
|
function update_terminalapp_cwd() {
|
|
# Identify the directory using a "file:" scheme URL, including
|
|
# the host name to disambiguate local vs. remote paths.
|
|
|
|
# Percent-encode the pathname.
|
|
local URL_PATH=''
|
|
{
|
|
# Use LANG=C to process text byte-by-byte.
|
|
local i ch hexch LANG=C
|
|
for ((i = 1; i <= ${#PWD}; ++i)); do
|
|
ch="$PWD[i]"
|
|
if [[ "$ch" =~ [/._~A-Za-z0-9-] ]]; then
|
|
URL_PATH+="$ch"
|
|
else
|
|
hexch=$(printf "%02X" "'$ch")
|
|
URL_PATH+="%$hexch"
|
|
fi
|
|
done
|
|
}
|
|
|
|
local PWD_URL="file://$HOST$URL_PATH"
|
|
printf '\e]7;%s\a' "$PWD_URL"
|
|
}
|
|
|
|
# Use a precmd hook instead of a chpwd hook to avoid contaminating output
|
|
precmd_functions+=(update_terminalapp_cwd)
|
|
# Run once to get initial cwd set
|
|
update_terminalapp_cwd
|
|
fi
|