mirror of
https://github.com/ohmyzsh/ohmyzsh.git
synced 2024-12-18 10:22:00 +00:00
6fbfc4c78b
* dotenv: add possibility to agree once for a given .env file * refactor: fix code style * Use :A modifier instead of readlink. Thanks Aloxaf * Use grep and clean up allowed list check logic * Simplify and reorder file; change default allowed list path * Add new feature to README * Make sure ZSH_CACHE_DIR is defined * Resolve symlinks in $PWD before storing in allowed list Co-authored-by: Aloxaf <bailong104@gmail.com> Co-authored-by: Marc Cornellà <marc.cornella@live.com>
46 lines
1.3 KiB
Bash
46 lines
1.3 KiB
Bash
## Settings
|
|
|
|
# Filename of the dotenv file to look for
|
|
: ${ZSH_DOTENV_FILE:=.env}
|
|
|
|
# Path to the file containing allowed paths
|
|
: ${ZSH_DOTENV_ALLOWED_LIST:="${ZSH_CACHE_DIR:-$ZSH/cache}/dotenv-allowed.list"}
|
|
|
|
|
|
## Functions
|
|
|
|
source_env() {
|
|
if [[ -f $ZSH_DOTENV_FILE ]]; then
|
|
if [[ "$ZSH_DOTENV_PROMPT" != false ]]; then
|
|
local confirmation dirpath="${PWD:A}"
|
|
|
|
# make sure there is an allowed file
|
|
touch "$ZSH_DOTENV_ALLOWED_LIST"
|
|
|
|
# check if current directory's .env file is allowed or ask for confirmation
|
|
if ! grep -q "$dirpath" "$ZSH_DOTENV_ALLOWED_LIST" &>/dev/null; then
|
|
# print same-line prompt and output newline character if necessary
|
|
echo -n "dotenv: found '$ZSH_DOTENV_FILE' file. Source it? ([Y]es/[n]o/[a]lways) "
|
|
read -k 1 confirmation; [[ "$confirmation" != $'\n' ]] && echo
|
|
|
|
# check input
|
|
case "$confirmation" in
|
|
[nN]) return ;;
|
|
[aA]) echo "$dirpath" >> "$ZSH_DOTENV_ALLOWED_LIST" ;;
|
|
*) ;; # interpret anything else as a yes
|
|
esac
|
|
fi
|
|
fi
|
|
|
|
# test .env syntax
|
|
zsh -fn $ZSH_DOTENV_FILE || echo "dotenv: error when sourcing '$ZSH_DOTENV_FILE' file" >&2
|
|
|
|
setopt localoptions allexport
|
|
source $ZSH_DOTENV_FILE
|
|
fi
|
|
}
|
|
|
|
autoload -U add-zsh-hook
|
|
add-zsh-hook chpwd source_env
|
|
|
|
source_env
|