From 6b0557afe84f671705029bf2a21002dfe9d07be5 Mon Sep 17 00:00:00 2001
From: deathjest3r <Death.Jester@web.de>
Date: Sat, 16 Jan 2021 21:27:32 +0100
Subject: [PATCH] feat(plugins): add `term_tab` plugin to complete other zsh
 sessions' directories (#3018)

---
 plugins/term_tab/README              | 16 +++++++++++
 plugins/term_tab/term_tab.plugin.zsh | 41 ++++++++++++++++++++++++++++
 2 files changed, 57 insertions(+)
 create mode 100644 plugins/term_tab/README
 create mode 100644 plugins/term_tab/term_tab.plugin.zsh

diff --git a/plugins/term_tab/README b/plugins/term_tab/README
new file mode 100644
index 000000000..316062e73
--- /dev/null
+++ b/plugins/term_tab/README
@@ -0,0 +1,16 @@
+
+term_tab - 'cwd' for all open zsh sessions
+******************************************
+
+What it does:
+*************
+This plugin allows to complete the 'cwd' of other Zsh sessions. Sounds
+complicated but is rather simple. E.g. if you have three zsh sessions open, in
+each session you are in a different folder, you can hit Ctrl+v in one session
+to show you the current working directory of the other open zsh sessions.
+
+How it works:
+*************
+* It uses 'pidof zsh' to determine all zsh PIDs
+* It reads procfs to get the current working directory of this session
+* Everything is fed into zsh's completion magic
diff --git a/plugins/term_tab/term_tab.plugin.zsh b/plugins/term_tab/term_tab.plugin.zsh
new file mode 100644
index 000000000..1b612df68
--- /dev/null
+++ b/plugins/term_tab/term_tab.plugin.zsh
@@ -0,0 +1,41 @@
+# Copyright (C) 2014 Julian Vetter <death.jester@web.de>
+#
+# This program is free software; you can redistribute it and/or modify
+# it under the terms of the GNU General Public License as published by
+# the Free Software Foundation; either version 2 of the License, or
+# (at your option) any later version.
+#
+# This program is distributed in the hope that it will be useful,
+# but WITHOUT ANY WARRANTY; without even the implied warranty of
+# MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
+# GNU General Public License for more details.
+#
+# You should have received a copy of the GNU General Public License
+# along with this program; if not, write to the Free Software
+# Foundation, Inc., 51 Franklin St, Fifth Floor, Boston, MA  02110-1301 USA
+
+function _term_list(){
+  local -a expl
+  local -au dirs
+
+  PREFIX="$IPREFIX$PREFIX"
+  IPREFIX=
+  SUFFIX="$SUFFIX$ISUFFIX"
+  ISUFFIX=
+
+  [[ -o magicequalsubst ]] && compset -P '*='
+
+  case $OSTYPE in
+    solaris*) dirs=( ${(M)${${(f)"$(pgrep -U $UID -x zsh|xargs pwdx)"}:#$$:*}%%/*} ) ;;
+    linux*) dirs=( /proc/${^$(pidof zsh):#$$}/cwd(N:A) ) ;;
+  esac
+  dirs=( ${(D)dirs} )
+
+  compstate[pattern_match]='*'
+  _wanted directories expl 'current directory from other shell' \
+      compadd -Q -M "r:|/=* r:|=*" -f -a dirs
+}
+
+zle -C term_list menu-complete _generic
+bindkey "^v" term_list
+zstyle ':completion:term_list::::' completer _term_list